什么才是提高ASP性能的最佳选择(续三)

作者:青苹果工作室编译 来源: 日期:2002-8-5
引用记录集中域值的最有效方法是什么? 

  到目前为止,我都是用名字引用记录集中的域值的。这可能是一种效率很低的方法,因为每次调用都需要查找域。为了证明这一点,下面的测试就要通过记录集中域的集合的指针来引用域(ADO__08.asp): 

 ’write data 
 Do While Not objRS.EOF 
  Response.Write( _ 
  "< TR >" & _ 
  "< TD >" & objRS(0) & "< /TD >" & _ 
  "< TD >" & objRS(1) & "< /TD >" & _ 
  "< TD >" & objRS(2) & "< /TD >" & _ 
  "< TD >" & objRS(3) & "< /TD >" & _ 
  "< TD >" & objRS(4) & "< /TD >" & _ 
  "< TD >" & objRS(5) & "< /TD >" & _ 
  "< TD >" & objRS(6) & "< /TD >" & _ 
  "< /TR > " _ 
  ) 
  objRS.MoveNext 
 Loop 

  正如我们所预料的,装载时间的变化很小(差异可能是由于代码上的轻微减少引起的)。但是这种技术在有效显示时间上却带来了明显的减少。 

  在下面的例子中,我们将给每个域指定一个单独的变量。这种方法避免了在表格循环内的所有查找( ADO__09.asp ): 

 If objRS.EOF Then 
  Response.Write("No Records Found") 
 Else 
  ’write headings 
  ... 
  Dim fld0 
  Dim fld1 
  Dim fld2 
  Dim fld3 
  Dim fld4 
  Dim fld5 
  Dim fld6 
  Set fld0 = objRS(0) 
  Set fld1 = objRS(1) 
  Set fld2 = objRS(2) 
  Set fld3 = objRS(3) 
  Set fld4 = objRS(4) 
  Set fld5 = objRS(5) 
  Set fld6 = objRS(6) 
  ’write data 
  Do While Not objRS.EOF 
  Response.Write( _ 
  "< TR >" & _ 
  "< TD >" & fld0 & "< /TD >" & _ 
  "< TD >" & fld1 & "< /TD >" & _ 
  "< TD >" & fld2 & "< /TD >" & _ 
  "< TD >" & fld3 & "< /TD >" & _ 
  "< TD >" & fld4 & "< /TD >" & _ 
  "< TD >" & fld5 & "< /TD >" & _ 
  "< TD >" & fld6 & "< /TD >" & _ 
  "< /TR >" _ 
  ) 
  objRS.MoveNext 
  Loop 
  Set fld0 = Nothing 
  Set fld1 = Nothing 
  Set fld2 = Nothing 
  Set fld3 = Nothing 
  Set fld4 = Nothing 
  Set fld5 = Nothing 
  Set fld6 = Nothing 
  Response.Write("< /TABLE >") 
 End If 

  到目前,这种方法形成的结果是最好的。每条记录的显示时间下降成了.45 毫秒。 

  现在,所有测试脚本的配置都要求对结果记录集有一些了解。比如说,我们一直在栏标题中给域名编码,单独地引用这些域的值。下面的例子提供了一个动态的解决方案,在域的集合中循环,不仅得到数据,也得到域的标题(ADO__10.asp ): 

 If objRS.EOF Then 
  Response.Write("No Records Found") 
 Else 
  ’write headings 
  Response.Write("< TABLE BORDER=1 >< TR >") 
  For Each objFld in objRS.Fields 
  Response.Write("< TH >" & objFld.name & "< /TH >") 
  Next 
  Response.Write("< /TR >") 
  ’write data 
  Do While Not objRS.EOF 
  Response.Write("< TR >") 
  For Each objFld in objRS.Fields 
  Response.Write("< TD >" & objFld.value & "< /TD >") 
  Next 
  Response.Write("< /TR >") 
  objRS.MoveNext 
  Loop 
  Response.Write("< /TABLE >") 
 End If 

 可以看到,我们在性能上有一个损失,但是这个方法还是比ADO__07.asp要快一些。 

  下面的测试是在最后两个测试之间进行一些折中。通过在一个动态分配数组中保存域的引用,既维持了动态的灵活性,也挽回了一些性能上的损失。 

 If objRS.EOF Then 
  Response.Write("No Records Found") 
 Else 
  Dim fldCount 
  fldCount = objRS.Fields.Count 
  Dim fld() 
  ReDim fld(fldCount) 
  Dim i 
  For i = 0 to fldCount-1 
  Set fld(i) = objRS(i) 
  Next 
  ’write headings 
  Response.Write("< TABLE BORDER=1 >< TR >") 
  For i = 0 to fldCount-1 
  Response.Write("< TH >" & fld(i).name & "< /TH >") 
  Next 
  Response.Write("< /TR >") 
  ’write data 
  Do While Not objRS.EOF 
  Response.Write("< TR >") 
  For i = 0 to fldCount-1 
  Response.Write("< TD >" & fld(i) & "< /TD >") 
  Next 
  Response.Write("< /TR >") 
  objRS.MoveNext 
  Loop 
  For i = 0 to fldCount-1 
  Set fld(i) = Nothing 
  Next 
  Response.Write("< /TABLE >") 
 End If 

  虽然它并不比最好值快,但是比前面的几个例子要快了很多,并且有一个优势就是能够动态地表现任何记录集。 

  在下一个测试中,我们将对以前的方案做一个彻底的改变,使用记录集的GetRows指令创建一个循环用的数组,而不是在记录集本身进行循环。注意,调用GetRows之后,立刻就将记录集设置为Nothing,这样就能更快地释放系统资源。另外还要注意数组的第一个维数代表域,第二个维数代表行 ( ADO__12.asp ): 

 If objRS.EOF Then 
  Response.Write("No Records Found") 
  objRS.Close 
  Set objRS = Nothing 
 Else 
  ’write headings 
  ... 
  ’set array 
  Dim arrRS 
  arrRS = objRS.GetRows 
  ’close recordset early 
  objRS.Close 
  Set objRS = Nothing 
  ’write data 
  Dim numRows 
  Dim numFlds 
  Dim row 
  Dim fld 
  numFlds = Ubound(arrRS, 1) 
  numRows = Ubound(arrRS, 2) 
  For row= 0 to numRows 
  Response.Write("< TR >") 
  For fld = 0 to numFlds 
  Response.Write("< TD >" & arrRS(fld, row) & "< /TD >") 
  Next 
  Response.Write("< /TR >") 
  Next 
  Response.Write("< /TABLE >") 
 End If 

  通过使用GetRows 指令,就可以获取整个记录集并将其装载到数组中。当恢复特别大的记录集时,这种方法有可能会造成资源问题,但是数据的循环快多了,因为类似于MoveNext 的函数调用和EOF 的检测都可以取消了。 

  不过速度的提升确实是有代价的,因为记录集的元数据不再与数据在一起。围绕这个问题,我在调用GetRows之前用记录集来恢复标题名。另外还可以提前提取数据类型和其它信息。还要注意,在我们的测试中,性能上的优势只有在使用大一些的记录集时才能看到。 

  在这部分最后的测试中,我们更进一步,使用记录集的GetString 指令。这个方法将整个记录集提取到一个大的字符串中,允许你指定自己的分隔符( ADO__13.asp ): 

 If objRS.EOF Then 
  Response.Write("No Records Found") 
  objRS.Close 
  Set objRS = Nothing 
 Else 
  ’write headings 
  ... 
  ’set array 
  Dim strTable 
  strTable = objRS.GetString (2, , "< /TD >< TD >", "< /TD >< /TR >< TR >< TD >") 
  ’close recordset early 
  objRS.Close 
  Set objRS = Nothing 
  Response.Write(strTable & "< /TD >< /TR >< /TABLE >") 
 End If 

  虽然这种方法已经接近了最高水平,但是它只适合于最简单的设计,因为它根本就不能应用于数据的特殊情况。 

观察 
  在我们开始这套测试之前,执行每条记录的时间一直在.83 毫秒左右震动。这套测试中的大多数方法都将这个数字减少了一半。虽然有些方法明显地提供了更快的速度,但是代价是灵活性的降低。 

  下面的规则是以重要程度为顺序的: 

* 当记录集中的值不需要用一种特殊方式来对待并且能够格式化为一种统一的格式时,使用GetString方法来提取数据。 
* 当你在设计上需要更大的灵活性,但是又不需要用记录集的元数据进行工作,使用GetRows 方法将数据提取到一个数组中。 
* 当你需要设计的灵活性和元数据时,在进入一个数据恢复的循环之前,将你的域约束在本地变量中。避免用名字引用域。 

使用临时字符串可以较好地代替缓冲器吗? 
  这是针对我上一篇文章提交的一些注解所引发的一个小小的离题。要讨论的问题是围绕着缓冲器的使用及使用临时字符串作为替代来收集输出,这样就允许Response.Write 只调用一次。为了测试,我从ADO_11.asp的代码开始,将结果附加到一个字符串中,而不是在每个循环都调用Response.Write,当整个操作都结束后,在字符串上调用Response.Write ( STR__01.asp ): 

  Dim strTable 
  strTable = "" 
  ’write headings 
  strTable = strTable & "< TABLE BORDER=1 >< TR >" 
  For i = 0 to fldCount-1 
  strTable = strTable & "< TH >" & fld(i).name & "< /TH >" 
  Next 
  strTable = strTable & "< /TR >" 
  ’write data 
  Do While Not objRS.EOF 
  strTable = strTable & "< TR >" 
  For i = 0 to fldCount-1 
  strTable = strTable & "< TD >" & fld(i) & "< /TD >" 
  Next 
  strTable = strTable & "< /TR >" 
  objRS.MoveNext 
  Loop 
  For i = 0 to fldCount-1 
  Set fld(i) = Nothing 
  Next 
  strTable = strTable & "< /TABLE >" 
  Response.Write(strTable) 

  看起来执行得不是很好。也许正象许多人建议的,我们应该用Space 指令为这个字符串指定一些空间,这样它就不需要在循环期间总是为自己重新分配空间( STR__02.asp ): 

  Dim strTable 
  strTable = Space(10000) 

  也许Space 指令并不象建议的那样工作。我们最后的规则是:不要用临时字符串来收集输出。
相关文章